Ошибка: Невозможно применить фиксированные настройки. Пересекаются элементы отбора

До 8.3.3.721 - Подробно про ошибку и решение через настройки Списка (элемента формы) можно прочитать здесь https://helpf.pro/faq/view/1715.html

Начиная с 8.3.3.721 добавлены новые события Динамического списка управляемой формы - V8Update 8.3.3.721: Динамический список. - и ошибку можно обойти программно

&НаСервере

Процедура СписокПередЗагрузкойПользовательскихНастроекНаСервере(Элемент, Настройки)

 ИсключитьПересеченияЭлементовОтбораПередЗагрузкойПользовательскихНастроек(ЭтаФорма, Элемент, Настройки);

КонецПроцедуры

&НаСервереБезКонтекста
// Исключает ошибку при открытии формы
// "Невозможно применить фиксированные настройки. Пересекаются элементы отбора"
// при открытии форм списка или выбора, где в свойствах списка установлено 
//  АвтоматическоеСохранениеПользовательскихНастроек = Истина
// Следует использовать в обработчике событий списка
//
// Параметры:
// Форма - УправляемаяФорма - ФормаСписка, ФормаВыбора
// Элемент - ТаблицаФормы -  Таблица, для которой выполняется загрузка настроек
//  Настройки - ПользовательскиеНастройкиКомпоновкиДанных - Загружаемые настройки
//
Процедура ИсключитьПересеченияЭлементовОтбораПередЗагрузкойПользовательскихНастроек(Форма, Элемент, Настройки) Экспорт 

 Отбор = ОбщегоНазначенияКлиентСервер.СвойствоСтруктуры(Форма.Параметры, "Отбор", Новый Структура());

 Для Каждого ЗначениеОтбора Из Отбор Цикл

  Для Каждого ЭлементНастройки Из Настройки.Элементы Цикл

   Если ТипЗнч(ЭлементНастройки) = Тип("ОтборКомпоновкиДанных") Тогда
    

    МассивУдаляемыхЭлементов = Новый Массив;

    Для Каждого ЭлементЭлементНастройки Из ЭлементНастройки.Элементы Цикл

     Если ЭлементЭлементНастройки.ЛевоеЗначение = Новый ПолеКомпоновкиДанных(ЗначениеОтбора.Ключ) Тогда

      МассивУдаляемыхЭлементов.Добавить(ЭлементЭлементНастройки);

     КонецЕсли;

    КонецЦикла;
    

    Для Каждого УдаляемыйЭлемент Из МассивУдаляемыхЭлементов Цикл

     ЭлементНастройки.Элементы.Удалить(УдаляемыйЭлемент);

    КонецЦикла;
    
   КонецЕсли;   
  КонецЦикла;
 КонецЦикла; 

КонецПроцедуры