Запросы. Объеденяем периоды действия

Прошлая задача с периодами обрела новую форму (и да, задача по прежнему упрощена - периоды в днях)

Нужно таблицу вида

Дата Начала  Дата Окончания
01.01.2015    11.01.2015
17.01.2015    18.01.2015
19.01.2015    20.01.2015
21.01.2015    22.01.2015
28.01.2015    28.01.2015

привести к таблице вида

Дата Начала Дата Окончания
01.01.2015    11.01.2015
17.01.2015    22.01.2015
28.01.2015    28.01.2015

Пришел к следующему решению, используя ранее накопленные знания

- Период по дням
- Собираем периоды действия

PROFIT!

ВЫБРАТЬ
 ДАТАВРЕМЯ(2015, 1, 1, 0, 0, 0) КАК ДатаНачала,
 ДАТАВРЕМЯ(2015, 1, 11, 0, 0, 0) КАК ДатаОкончания
ПОМЕСТИТЬ втПериоды

ОБЪЕДИНИТЬ ВСЕ

ВЫБРАТЬ
 ДАТАВРЕМЯ(2015, 1, 17, 0, 0, 0),
 ДАТАВРЕМЯ(2015, 1, 18, 0, 0, 0)

ОБЪЕДИНИТЬ ВСЕ

ВЫБРАТЬ
 ДАТАВРЕМЯ(2015, 1, 19, 0, 0, 0),
 ДАТАВРЕМЯ(2015, 1, 20, 0, 0, 0)

ОБЪЕДИНИТЬ ВСЕ

ВЫБРАТЬ
 ДАТАВРЕМЯ(2015, 1, 21, 0, 0, 0),
 ДАТАВРЕМЯ(2015, 1, 22, 0, 0, 0)

ОБЪЕДИНИТЬ ВСЕ

ВЫБРАТЬ
 ДАТАВРЕМЯ(2015, 1, 28, 0, 0, 0),
 ДАТАВРЕМЯ(2015, 1, 28, 0, 0, 0)
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
 0 КАК Поле1
ПОМЕСТИТЬ втЧисла

ОБЪЕДИНИТЬ ВСЕ

ВЫБРАТЬ
 1

ОБЪЕДИНИТЬ ВСЕ

ВЫБРАТЬ
 2

ОБЪЕДИНИТЬ ВСЕ

ВЫБРАТЬ
 3

ОБЪЕДИНИТЬ ВСЕ

ВЫБРАТЬ
 4

ОБЪЕДИНИТЬ ВСЕ

ВЫБРАТЬ
 5

ОБЪЕДИНИТЬ ВСЕ

ВЫБРАТЬ
 6

ОБЪЕДИНИТЬ ВСЕ

ВЫБРАТЬ
 7

ОБЪЕДИНИТЬ ВСЕ

ВЫБРАТЬ
 8

ОБЪЕДИНИТЬ ВСЕ

ВЫБРАТЬ
 9
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
 втЧисла1.Поле1 + втЧисла10.Поле1 * 10 + втЧисла100.Поле1 * 100 + втЧисла1000.Поле1 * 1000 КАК Поле1
ПОМЕСТИТЬ втЛинейка
ИЗ
 втЧисла КАК втЧисла1,
 втЧисла КАК втЧисла10,
 втЧисла КАК втЧисла100,
 втЧисла КАК втЧисла1000
ГДЕ
 втЧисла1.Поле1 + втЧисла10.Поле1 * 10 + втЧисла100.Поле1 * 100 + втЧисла1000.Поле1 * 1000 <= РАЗНОСТЬДАТ(&Дата1, &Дата2, ДЕНЬ)
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
 ДОБАВИТЬКДАТЕ(&Дата1, ДЕНЬ, втЛинейка.Поле1) КАК Дата
ПОМЕСТИТЬ втВсеДаты
ИЗ
 втЛинейка КАК втЛинейка
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
 втВсеДаты.Дата
ПОМЕСТИТЬ втДаты
ИЗ
 втПериоды КАК втПериоды
  ВНУТРЕННЕЕ СОЕДИНЕНИЕ втВсеДаты КАК втВсеДаты
  ПО (втВсеДаты.Дата МЕЖДУ втПериоды.ДатаНачала И втПериоды.ДатаОкончания)
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
 втДаты.Дата КАК ДатаНачала,
 ЕСТЬNULL(втДатыСправа.Дата, втДаты.Дата) КАК ДатаОкончания
ПОМЕСТИТЬ втВариации
ИЗ
 втДаты КАК втДаты
  ЛЕВОЕ СОЕДИНЕНИЕ втДаты КАК втДатыСправа
  ПО втДаты.Дата < втДатыСправа.Дата
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
 МИНИМУМ(НеСгруппированныеПериодыСправа.ДатаНачала) КАК ДатаНачала,
 НеСгруппированныеПериодыСправа.ДатаОкончания
ИЗ
 (ВЫБРАТЬ
  НеСгруппированныеПериодыСправа.ДатаНачала КАК ДатаНачала,
  МАКСИМУМ(НеСгруппированныеПериодыСправа.ДатаОкончания) КАК ДатаОкончания
 ИЗ
  (ВЫБРАТЬ
   втВариации.ДатаНачала КАК ДатаНачала,
   втВариации.ДатаОкончания КАК ДатаОкончания
  ИЗ
   втВариации КАК втВариации
    ВНУТРЕННЕЕ СОЕДИНЕНИЕ втДаты КАК втДаты
    ПО втВариации.ДатаНачала <= втДаты.Дата
     И втВариации.ДатаОкончания >= втДаты.Дата
  
  СГРУППИРОВАТЬ ПО
   втВариации.ДатаНачала,
   втВариации.ДатаОкончания
  
  ИМЕЮЩИЕ
   КОЛИЧЕСТВО(НАЧАЛОПЕРИОДА(втДаты.Дата, ДЕНЬ)) - 1 = РАЗНОСТЬДАТ(втВариации.ДатаНачала, втВариации.ДатаОкончания, ДЕНЬ)) КАК НеСгруппированныеПериодыСправа
 
 СГРУППИРОВАТЬ ПО
  НеСгруппированныеПериодыСправа.ДатаНачала) КАК НеСгруппированныеПериодыСправа

СГРУППИРОВАТЬ ПО
 НеСгруппированныеПериодыСправа.ДатаОкончания