xUnitFor1C и Обычное приложение.

Вводная: спросили, как?

Пример упавшего теста xUnitFor1C в Обычном приложении

Взял https://github.com/xDrivenDevelopment/xUnitFor1C

Обычного под руками ничего не было. Взял версию БСП 2.0.1.19 (для 8.2), включил запуск в обычном приложении, при первой попытке запуска xddTestRunner.epf получил ошибки связанные с методами платформы, которых из-за режима совместимости ещё не было.

Добавил глобальный модуль с заплатками (можно было поправить и релиз xUnitFor1C, но было быстрее в самой конфигурации сделать заплатку)

Функция СтрШаблон(Знач СтрокаПодстановки,
 Знач Параметр1, Знач Параметр2 = Неопределено, Знач Параметр3 = Неопределено,
 Знач Параметр4 = Неопределено, Знач Параметр5 = Неопределено, Знач Параметр6 = Неопределено,
 Знач Параметр7 = Неопределено, Знач Параметр8 = Неопределено, Знач Параметр9 = Неопределено) Экспорт
 
 Возврат СтроковыеФункцииКлиентСервер.ПодставитьПараметрыВСтроку(
 СтрокаПодстановки, Параметр1, Параметр2, Параметр3, Параметр4, Параметр5, Параметр6, Параметр7, Параметр8, Параметр9);
 
КонецФункции

Функция СтрНайти(Строка, ПодстрокаПоиска, 
 НаправлениеПоиска = Неопределено, НачальнаяПозиция = 0, НомерВхождения = Неопределено) Экспорт
 
 Если ЗначениеЗаполнено(НаправлениеПоиска) Тогда
  ВызватьИсключение "НаправлениеПоиска";
 КонецЕсли;
 
 Если ЗначениеЗаполнено(НачальнаяПозиция) Тогда
  ВызватьИсключение "НачальнаяПозиция";
 КонецЕсли;
 
 Если ЗначениеЗаполнено(НомерВхождения) Тогда
  ВызватьИсключение "НомерВхождения";
 КонецЕсли;
 
 Возврат Найти(Строка, ПодстрокаПоиска);
 
КонецФункции

Дальше проверил только интерактивную работу -  запускаем  xddTestRunner.epf  из корня репозитория проекта. Загружаем тесты из каталога \ выборочно из файлов, сами тесты внешние обработки, примеры можно посмотреть там же в подкаталоге \Tests.

или делаем свою с модулем объекта, например так

Перем КонтекстЯдра;
Перем Утверждения;

Процедура Инициализация(КонтекстЯдраПараметр) Экспорт
 КонтекстЯдра = КонтекстЯдраПараметр;
 Утверждения = КонтекстЯдра.Плагин("БазовыеУтверждения");
КонецПроцедуры

Функция ПолучитьСписокТестов() Экспорт
 ВсеТесты = Новый Массив;
 
 ВсеТесты.Добавить("ТестДолжен_ПроверитьЧтоТо");
 ВсеТесты.Добавить("ТестДолжен_ПроверитьЕщёЧтоТо");
 ВсеТесты.Добавить("ТестДолжен_Провалиться");
 
 Возврат ВсеТесты;
КонецФункции

Процедура ТестДолжен_ПроверитьЧтоТо() Экспорт
 
 Утверждения.Проверить(Истина, "Это не была истина");
 
КонецПроцедуры

Процедура ТестДолжен_ПроверитьЕщёЧтоТо() Экспорт
 
 Утверждения.Проверить(Истина, "Это не была истина");
 
КонецПроцедуры

Процедура ТестДолжен_Провалиться() Экспорт
 
 Утверждения.Проверить(Ложь, "Это не была истина");
 
КонецПроцедуры

Для обычного приложения достаточно уже этого.

Про плагины

Утверждения = КонтекстЯдра.Плагин("БазовыеУтверждения");

все они лежат в каталоге \Plugins репозитория

А в качестве документации можно воспользоваться каталогом исходников репозитория, например

src/Plugins/БазовыеУтверждения/ObjectModule.bsl

или открывать обработки из каталога \Plugins.